:開始
@echo off
REM =============環境に応じて、修正してください。=====================================
set COPY_TOPIC=移行
set COPY_NAME=####
set COPY_SRC_DIR=d:\test\####
set COPY_DST_DIR=d:\testd\####
set COPY_LOG_DIR=d:\admtools\log
REM ==================================================================================
set YYYYMMDD=%date:~0,4%%date:~5,2%%date:~8,2%
set Time_edit=%time: =0%
set HHMMSS=%Time_edit:~0,2%%Time_edit:~3,2%%Time_edit:~6,2%
set Copy_options=/COPY:DATSO /MIR
set Excludes_files="" ""
set Excludes_directories="" "" ""
set File_selection_options=
set Retry_options=/R:0 /W:1
set Log_file="%COPY_LOG_DIR%\%COPY_TOPIC%_%COPY_NAME%_%YYYYMMDD%_%HHMMSS%.log"
rem set Logging_options=/TEE /LOG:%Log_file%
rem set Logging_options=/TEE /FP /LOG:%Log_file%
rem set Logging_options=/TEE /X /FP /LOG:%Log_file%
set Logging_options=/TEE /V /X /FP /LOG:%Log_file%
set Source="%COPY_SRC_DIR%"
set Destination="%COPY_DST_DIR%"
REM set File=*.*
set Options=%Copy_options% %File_selection_options% %Retry_options% %Logging_options%
:: 自動生成した、ROBOCOPY実行コマンドを画面表示で確認する
echo.
echo ↓↓↓↓↓ 自動生成した、ROBOCOPY実行コマンド ここから ↓↓↓↓↓
echo.
echo robocopy.exe %Source% %Destination% %Options%
echo.
echo ↑↑↑↑↑ 自動生成した、ROBOCOPY実行コマンド ここまで ↑↑↑↑↑
set Console_input=""
echo.
echo ******************************************************************************
echo *
echo * 重要！！ バッチ処理実行確認
echo * トピック ：%COPY_TOPIC%
echo * 移行フォルダ ：%COPY_NAME%
echo * コピー元 ：%COPY_SRC_DIR%
echo * コピー先 ：%COPY_DST_DIR%
echo * 移行ログパス ：%COPY_LOG_DIR%
echo * 移行ログ名前 ：%Log_file%
echo *
echo * 自動生成した、ROBOCOPY実行コマンドを確認し、処理続行選択について、
echo * 以下のように入力してください（大文字と小文字は区別しません）。
echo *
echo * start ：ROBOCOPYの実行を開始します
echo * quit ：ROBOCOPYの実行を中止し、当バッチ処理を打ち切ります
echo * 上記以外の文字列 ：当バッチ処理の先頭に戻ります
echo * （ログファイル名の日時も更新されます）
echo *
echo ******************************************************************************
echo.
set /P Console_input="処理続行選択（上記参照） : "
if /I "%Console_input%"=="quit" exit
if /I "%Console_input%"=="start" goto ROBOCOPY実行
goto 開始
pause
:ROBOCOPY実行
REM ★★★デイレクリがなければ作成する。
mkdir %COPY_DST_DIR%\%COPY_NAME%
robocopy.exe %Source% %Destination% %Options%
pause
rem exit
